#################################################
#　再生時間チェッカー
#　　　by　とむやん
#
#
#################################################

#あくまでもオマケツールです。
#チェックする曲は自分で指定してください。
#（指定する場所は５０行目あたりにあります）

!文字列操作 , ${文字列:tomyun/PicList} , = , [ロード画像]アーサ・アルバート.jpg\n[ロード画像]シンシズナ.jpg\n[ロード画像]ナナシ・シシト.jpg\n
!文字列操作 , ${文字列:tomyun/PicList} , += , [ロード画像]シーナ.jpg\n[ロード画像]ナダ.png\n[ロード画像]メアリー.png\n[ロード画像]予告のお姉さん\n[ロード画像]狐狩妖子\n
!文字列操作 , ${文字列:tomyun/PicList} , += , [ロード画像][氷野]セト.jpg\n[カットイン][氷野]ウリユ.jpg\n[カットイン][氷野]モモセ.jpg\n
!文字列操作 , ${文字列:tomyun/PicList} , += , [カットイン]シーナ.jpg\n[カットイン]シンシズナ.jpg\n[カットイン]ナダ.png\n[カットイン]メアリー.png\n[カットイン]狐狩妖子.jpg\n[カットイン]予告のお姉さん.jpg\n
!文字列操作 , ${文字列:tomyun/PicPath} , = , DataOfficial\WallPaper\

#画像チェック処理
!変数操作 , ${変数:TMP} , = , 0
!文字列操作 , ${文字列:TMP} , →の上1行コピー , ${文字列:tomyun/PicList}
!文字列操作 , ${文字列:tomyun/PicList} , ←の上1行消去 , 
!ラベル , 画像チェックループ

!条件分岐 , ${文字列:TMP} ,  , と同じ
!ジャンプ , 画像チェックループ終了
!条件終了

!条件分岐 , ${ファイル有無: ..\${文字列:tomyun/PicPath}${文字列:TMP} } , 1 , と同じ
!文字列操作 , ${文字列:tomyun/PicShowList} , += , ${文字列:TMP}\n
!変数操作 , ${変数:TMP} , += , 1
!条件終了

!文字列操作 , ${文字列:TMP} , →の上1行コピー , ${文字列:tomyun/PicList}
!文字列操作 , ${文字列:tomyun/PicList} , ←の上1行消去 , 

!条件分岐 , ${文字列:TMP} ,   , 以外
!ジャンプ , 画像チェックループ
!条件終了

!変数操作 , ${変数:tomyun/PicMax} , = , ${変数:TMP}
!条件分岐 , ${変数:tomyun/PicMax} , 0 , と同じ
!変数操作 , ${変数:tomyun/NoPicFlag} , = , 1
!条件終了

＠なし
再生を開始します。
（\c[1]右クリック\c[0]で終了）

##ここでチェックする曲を指定◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆
!BGM , ボス戦3
##◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆◆

!変数操作 , ${セルフ変数:A} , = , 0
!変数操作 , ${セルフ変数:B} , = , 2
!変数操作 , ${セルフ変数:C} , = , 179
!変数操作 , ${セルフ変数:K} , = , 0

!ラベル , ループ前


#画像関連処理====Flagが0（画像無し）ならばスキップ
!条件分岐 , ${変数:tomyun/NoPicFlag} , 0 , と同じ
#画像関連処理
!変数操作 , ${セルフ変数:C} , += , 1


!!条件分岐 , ${セルフ変数:C} , 180 , 以上
#画像チェンジ
!!!条件分岐 , ${文字列:tomyun/PicShowingList} ,  , と同じ
!変数操作 , ${変数:tomyun/ShowPicMax} , = , ${変数:tomyun/PicMax}
!文字列操作 , ${文字列:tomyun/PicShowingList} , += , ${文字列:tomyun/PicShowList}
!!!条件終了
!変数操作 , ${変数:TMP} , = , ${変数:tomyun/ShowPicMax}
!変数操作 , ${セルフ変数:D} , = , 0
!文字列操作 , ${文字列:TMP} , = , ${文字列:tomyun/PicShowingList}
!文字列操作 , ${文字列:TMP2} , = , 

#====画像をリストから抽出=======
!ラベル , 画像決定用ループ
!文字列操作 , ${文字列:TMP2} , →の上1行コピー , ${文字列:TMP}
!文字列操作 , ${文字列:TMP} , ←の上1行消去 , 
!変数操作 , ${セルフ変数:D} , += , 1
!!!条件分岐 , ${セルフ変数:D} , ${変数:TMP} , 未満
!ジャンプ , 画像決定用ループ
!!!条件終了

!変数操作 , ${変数:tomyun/ShowPicMax} , -= , 1
!文字列操作 , ${文字列:tomyun/PicShowingList} , -= , ${文字列:TMP2}\n

#====画像をリストから抽出ここまで=======

!ピクチャ , ${セルフ変数:K} , 180 , 消去 , 
!変数操作 , ${セルフ変数:K} , += , 1
!!!条件分岐 , ${セルフ変数:K} , 30 , 以上
!変数操作 , ${セルフ変数:K} , = , 1
!!!条件終了
!ピクチャ , ${セルフ変数:K} , 180 , ${文字列:tomyun/PicPath}${文字列:TMP2} , 320,240,100,中心
!変数操作 , ${セルフ変数:C} , = , 0

!!条件終了

!条件終了

!ウェイト , 10
!変数操作 , ${セルフ変数:A} , += , 10

!条件分岐 , ${システム:マウス右クリック状態} , 1 , 以外
!ジャンプ , ループ前
!条件終了


!ピクチャ , ${セルフ変数:K} , 0 , 消去 , 
!BGM , 
!SE , 注目
＠なし
今回の再生時間は
\c[1]${セルフ変数:A:全角}\c[0]　です。